SUBROUTINE DISPLAYPARAMS_A
     * List the parameters available to this RealWeb page.

     * Include the RealWeb definitions
     INCLUDE #RW.INCLUDE.DEFS FROM /SYSFILES/REALWEB,BP

     EQU AM TO CHAR(254)

     * Start the HTML page.
     * Display the text 'List Parameters' in the browser's title bar.
     CALL RW_START_HTML_PAGE("List Parameters", "", "", "", "")

     * Insert a heading containing descriptive text.
     CALL RW_HEADING(1, "Parameters")

     * Get the list of parameters.
     PARAMS = ""
     * With the final parameter (Control) set to RWD_ALL,
     * RWA_DISPLAY_PARAMS retrieves all the parameters.
     * To limit the list to local parameters, use RWD_LOCAL.
     CALL RWA_DISPLAY_PARAMS(PARAMS, RWD_ALL)

     * Convert the parameter list to a dynamic array.
     PARAMS = CHANGE(PARAMS, "<BR>":CHAR(10), AM)

     * Remove any remaining HTML markup.
     PS = 1
     LOOP WHILE PS <> 0 DO
          PS = INDEX(PARAMS, "<", 1)
          PE = INDEX(PARAMS, ">", 1)
          HTML = PARAMS[PS, PE]
          PARAMS = CHANGE(PARAMS, HTML, "")
     REPEAT

     * Initialise variables
     PLIST = ""
     VLIST = ""
     * For each parameter in the list...
     N = 1
     FOR I = 1 TO DCOUNT(PARAMS, AM)
          * Extract its name and value...
          IF INDEX(PARAMS<I>, "=", 1) <> 0 THEN
               PLIST<N> = FIELD(PARAMS<I>, "=", 1)
               VLIST<N> = FIELD(PARAMS<I>, "=", 2)
               N = N + 1
          END
     NEXT I

     * Display the parameters as a definition list.
     CALL RW_MAKE_DLIST(PLIST, VLIST, "")

     * Complete the page.
     CALL RW_END_PAGE
RETURN

Go to top button